1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
|
// defines
// SKIN_1BONE
// SKIN_2BONES
// SKIN_4BONES
// LOOP_NAME
// VERTEX_SZ
// skin types
// SKIN_POS
// SKIN_POS_NRM
// SKIN_POS_NRM_TAN
//r0: const void* bones4x4
//r1: const void* srcVertData
//r2: const void* srcVertDataEnd
//r3: const BoneInfluence4* srcBoneInfluence4
//[sp+0] -> r4: const void* dstVertData
// s0,s1,s2 <- output: pos
// s3,s4,s5 <- output: nrm
// s6,s7,s8,s9 <- output: tan
// s10,s11,s12 <- input: pos
// s13,s14,s15 <- input: nrm
// s16,s17,s18,s19 <- input: tan
// s20-s31 <- matrix [3x4] last row loaded directly to output pos
//===========================================================================================================================================
//
// Common
#define CALC_POS_2 FMACS3 (0,1,2, 20,21,22, 10,10,10)
#define CALC_POS_3 FMACS3 (0,1,2, 24,25,26, 11,11,11)
#define CALC_POS_4 FMACS3 (0,1,2, 28,29,30, 12,12,12)
#if (SKIN_1BONE == SKIN_POS_NRM) || (SKIN_1BONE == SKIN_POS_NRM_TAN) \
|| (SKIN_2BONES == SKIN_POS_NRM) || (SKIN_2BONES == SKIN_POS_NRM_TAN) \
|| (SKIN_4BONES == SKIN_POS_NRM) || (SKIN_4BONES == SKIN_POS_NRM_TAN)
#define LOAD_POS_NRM vldmia.32 r1!, {s10-s15}
#define STORE_POS_NRM vstmia.32 r4!, {s0-s5}
#define CALC_NRM_1 FMULS3 (3,4,5, 20,21,22, 13,13,13)
#define CALC_NRM_2 FMACS3 (3,4,5, 24,25,26, 14,14,14)
#define CALC_NRM_3 FMACS3 (3,4,5, 28,29,30, 15,15,15)
#else
#define LOAD_POS_NRM vldmia.32 r1!, {s10-s12}
#define STORE_POS_NRM vstmia.32 r4!, {s0-s2}
#define CALC_NRM_1
#define CALC_NRM_2
#define CALC_NRM_3
#endif
#if (SKIN_1BONE == SKIN_POS_NRM_TAN) || (SKIN_2BONES == SKIN_POS_NRM_TAN) || (SKIN_4BONES == SKIN_POS_NRM_TAN)
#define LOAD_TAN vldmia.32 r1!, {s16-s19}
#define STORE_TAN vstmia.32 r4!, {s6-s9}
#define CALC_TAN_1 FMULS3 (6,7,8, 20,21,22, 16,16,16)
#define CALC_TAN_2 FMACS3 (6,7,8, 24,25,26, 17,17,17)
#define CALC_TAN_3 FMACS3 (6,7,8, 28,29,30, 18,18,18)
#define CALC_TAN_4 fcpys s9, s19
#else
#define LOAD_TAN
#define STORE_TAN
#define CALC_TAN_1
#define CALC_TAN_2
#define CALC_TAN_3
#define CALC_TAN_4
#endif
//===========================================================================================================================================
//
// 1 bone skinning
#if (SKIN_1BONE == SKIN_POS) || (SKIN_1BONE == SKIN_POS_NRM) || (SKIN_1BONE == SKIN_POS_NRM_TAN)
mov ip, sp
vpush {d7-d15}
stmfd sp!, {r4,r5,r6,r7,r8,r10,r11}
ldr r4, [ip, #0]
ldr r5, [r3], #4
add r5, r0, r5, lsl #6
add r6, r5, #48
vldmia.32 r6, {s0-s2}
vldmia.32 r5!, {s20-s23}
vldmia.32 r5!, {s24-s27}
.align 4
LOOP_NAME:
LOAD_POS_NRM
CALC_POS_2
CALC_NRM_1
ldr r6, [r3], #4 // next matrix index
vldmia.32 r5, {s28-s30} // bone matrix
add r5, r0, r6, lsl #6 // next matrix addr
CALC_POS_3
CALC_NRM_2
LOAD_TAN
add r6, r5, #48
cmp r1, r2
CALC_TAN_1
vldmiacc.32 r5!, {s20-s23} // next bone matrix
CALC_POS_4
CALC_TAN_2
CALC_NRM_3
vldmiacc.32 r5!, {s24-s27} // next bone matrix
CALC_TAN_3
CALC_TAN_4
pld [r1, #1024]
STORE_POS_NRM
STORE_TAN
vldmiacc.32 r6, {s0-s2}
bcc LOOP_NAME
ldmfd sp!, {r4,r5,r6,r7,r8,r10,r11}
vpop {d7-d15}
bx lr
//===========================================================================================================================================
#elif (SKIN_2BONES == SKIN_POS) || (SKIN_2BONES == SKIN_POS_NRM) || (SKIN_2BONES == SKIN_POS_NRM_TAN)
mov ip, sp
vpush {d7-d15}
stmfd sp!, {r4,r5,r6,r7,r8,r10,r11}
ldr r4, [ip, #0]
.align 4
LOOP_NAME:
vldmia.32 r3!, {s3,s4} // w
ldmia r3!, {r5-r6} // idx
add r5, r0, r5, lsl #6 // M0
add r6, r0, r6, lsl #6 // M1
vldmia.64 r5!, {d4,d5} // M0[0]
vldmia.64 r6!, {d6,d7} // M1[0]
FMULS3 (20,21,22, 8,9,10, 3,3,3) // M0[0] * w
vldmia.64 r5!, {d4,d5} // M0[1]
FMACS3 (20,21,22, 12,13,14, 4,4,4) // + M1[0] * w
vldmia.64 r6!, {d6,d7} // M1[1]
FMULS3 (24,25,26, 8,9,10, 3,3,3) // M0[1] * w
vldmia.64 r5!, {d4,d5} // M0[2]
FMACS3 (24,25,26, 12,13,14, 4,4,4) // + M1[1] * w
vldmia.64 r6!, {d6,d7} // M1[2]
FMULS3 (28,29,30, 8,9,10, 3,3,3) // M0[2] * w
vldmia.64 r5!, {d4,d5} // M0[3]
FMACS3 (28,29,30, 12,13,14, 4,4,4) // + M1[2] * w
vldmia.64 r6!, {d6,d7} // M1[3]
FMULS3 (0,1,2, 8,9,10, 3,3,3) // M0[3] * w
FMACS3 (0,1,2, 12,13,14, 4,4,4) // + M1[3] * w
LOAD_POS_NRM
LOAD_TAN
CALC_POS_2
CALC_NRM_1
CALC_TAN_1
CALC_POS_3
CALC_NRM_2
CALC_TAN_2
pld [r1, #1024]
cmp r1, r2
CALC_POS_4
CALC_NRM_3
CALC_TAN_3
CALC_TAN_4
STORE_POS_NRM
STORE_TAN
bcc LOOP_NAME
ldmfd sp!, {r4,r5,r6,r7,r8,r10,r11}
vpop {d7-d15}
bx lr
//===========================================================================================================================================
#elif (SKIN_4BONES == SKIN_POS) || (SKIN_4BONES == SKIN_POS_NRM) || (SKIN_4BONES == SKIN_POS_NRM_TAN)
mov ip, sp
vpush {d7-d15}
stmfd sp!, {r4,r5,r6,r7,r8}
ldr r4, [ip, #0]
.align 4
LOOP_NAME:
vldmia.32 r3!, {s3-s6} // w
ldmia r3!, {r5-r8} // idx
add r5, r0, r5, lsl #6 // M0
add r6, r0, r6, lsl #6 // M1
add r7, r0, r7, lsl #6 // M2
add r8, r0, r8, lsl #6 // M3
vldmia.64 r5!, {d4,d5} // M0[0]
vldmia.64 r6!, {d6,d7} // M1[0]
FMULS3 (20,21,22, 8,9,10, 3,3,3) // M0[0] * w
vldmia.64 r7!, {d4,d5} // M2[0]
FMACS3 (20,21,22, 12,13,14, 4,4,4) // + M1[0] * w
vldmia.64 r8!, {d6,d7} // M3[0]
FMACS3 (20,21,22, 8,9,10, 5,5,5) // + M2[0] * w
vldmia.64 r5!, {d4,d5} // M0[1]
FMACS3 (20,21,22, 12,13,14, 6,6,6) // + M3[0] * w
vldmia.64 r6!, {d6,d7} // M1[1]
FMULS3 (24,25,26, 8,9,10, 3,3,3) // M0[1] * w
vldmia.64 r7!, {d4,d5} // M2[1]
FMACS3 (24,25,26, 12,13,14, 4,4,4) // + M1[1] * w
vldmia.64 r8!, {d6,d7} // M3[1]
FMACS3 (24,25,26, 8,9,10, 5,5,5) // + M2[1] * w
vldmia.64 r5!, {d4,d5} // M0[2]
FMACS3 (24,25,26, 12,13,14, 6,6,6) // + M3[1] * w
vldmia.64 r6!, {d6,d7} // M1[2]
FMULS3 (28,29,30, 8,9,10, 3,3,3) // M0[2] * w
vldmia.64 r7!, {d4,d5} // M2[2]
FMACS3 (28,29,30, 12,13,14, 4,4,4) // + M1[2] * w
vldmia.64 r8!, {d6,d7} // M3[2]
FMACS3 (28,29,30, 8,9,10, 5,5,5) // + M2[2] * w
vldmia.64 r5!, {d4,d5} // M0[3]
FMACS3 (28,29,30, 12,13,14, 6,6,6) // + M3[2] * w
vldmia.64 r6!, {d6,d7} // M1[3]
FMULS3 (0,1,2, 8,9,10, 3,3,3) // M0[3] * w
vldmia.64 r7!, {d4,d5} // M2[3]
FMACS3 (0,1,2, 12,13,14, 4,4,4) // + M1[3] * w
vldmia.64 r8!, {d6,d7} // M3[3]
FMACS3 (0,1,2, 8,9,10, 5,5,5) // + M2[3] * w
FMACS3 (0,1,2, 12,13,14, 6,6,6) // + M3[3] * w
LOAD_POS_NRM
LOAD_TAN
CALC_POS_2
CALC_NRM_1
CALC_TAN_1
CALC_POS_3
CALC_NRM_2
CALC_TAN_2
pld [r1, #1024]
cmp r1, r2
CALC_POS_4
CALC_NRM_3
CALC_TAN_3
CALC_TAN_4
STORE_POS_NRM
STORE_TAN
bcc LOOP_NAME
ldmfd sp!, {r4,r5,r6,r7,r8}
vpop {d7-d15}
bx lr
#endif
//===========================================================================================================================================
#undef CALC_POS_1
#undef CALC_POS_2
#undef CALC_POS_3
#undef STORE_POS_NRM
#undef LOAD_POS_NRM
#undef CALC_NRM_1
#undef CALC_NRM_2
#undef CALC_NRM_3
#undef LOAD_TAN
#undef STORE_TAN
#undef CALC_TAN_1
#undef CALC_TAN_2
#undef CALC_TAN_3
#undef CALC_TAN_4
|
