1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
|
// defines
// LOOP_XYZ
// LOOP_XYZN
// LOOP_XYZNT
// LOOP_SPRITE
// LOOP_NAME
// COPY_DATA_SZ
// STRIDED_INPUT
#if STRIDED_INPUT
//r0: const void* srcData
//r1: const void* srcDataEnd
//r2: const void* addData
//r3: const void* xform
//[sp+0]: void* dstData
//[sp+4]: const int stride
//[sp+8]: const void* tangent
mov ip, sp
vpush {d0-d15}
stmfd sp!, {r4-r11}
// {s16-s31} xform
vldmia.32 r3!, {s16-s31}
// r3: dstData
// r4: stride
//r11: tangent
ldr r3, [ip, #0]
ldr r4, [ip, #4]
#if LOOP_XYZNT
ldr r11, [ip, #8]
#endif
#if LOOP_SPRITE
//r6: color
ldr r6, [ip, #8]
#endif
mov ip, r0
// VFP_VECTOR_LENGTH(3)
mov r0, ip
#if LOOP_XYZ
.align 4
LOOP_NAME:
mov r5, r0
pld [r0, #512] // prefetch
vldmia.32 r5!, {s0-s2} // load pos
FCPYS4 (8,9,10,11, 28,29,30,31) // pos.w
FMACS4 (8,9,10,11, 16,17,18,19, 0,0,0,0) // pos.x
#if COPY_DATA_SZ == 1
ldmia r2, {r6} // load additional data
#elif COPY_DATA_SZ == 2
ldmia r2, {r6-r7} // load additional data
#elif COPY_DATA_SZ == 3
ldmia r2, {r6-r8} // load additional data
#elif COPY_DATA_SZ == 4
ldmia r2, {r6-r9} // load additional data
#elif COPY_DATA_SZ == 5
ldmia r2, {r6-r10} // load additional data
#endif
FMACS4 (8,9,10,11, 20,21,22,23, 1,1,1,1) // pos.y
add r0, r0, r4 // inc srcData
FMACS4 (8,9,10,11, 24,25,26,27, 2,2,2,2) // pos.z
add r2, r2, r4 // inc srcAddData
vstmia.32 r3!, {s8-s10} // store pos
cmp r0, r1 // check cycle
#if COPY_DATA_SZ == 1
stmia r3!, {r6} // save additional data
#elif COPY_DATA_SZ == 2
stmia r3!, {r6-r7} // save additional data
#elif COPY_DATA_SZ == 3
stmia r3!, {r6-r8} // save additional data
#elif COPY_DATA_SZ == 4
stmia r3!, {r6-r9} // save additional data
#elif COPY_DATA_SZ == 5
stmia r3!, {r6-r10} // save additional data
#endif
bcc LOOP_NAME
#elif LOOP_XYZN
.align 4
LOOP_NAME:
mov r5, r0
pld [r0, #512] // prefetch
vldmia.32 r5!, {s0-s2} // load pos
FCPYS4 (8,9,10,11, 28,29,30,31) // pos.w
vldmia.32 r5!, {s3-s5} // load normal
FMACS4 (8,9,10,11, 16,17,18,19, 0,0,0,0) // pos.x
FMULS4 (12,13,14,15, 16,17,18,19, 3,3,3,3) // normal.x
FMACS4 (8,9,10,11, 20,21,22,23, 1,1,1,1) // pos.y
#if COPY_DATA_SZ == 1
ldmia r2, {r6} // load additional data
#elif COPY_DATA_SZ == 2
ldmia r2, {r6-r7} // load additional data
#elif COPY_DATA_SZ == 3
ldmia r2, {r6-r8} // load additional data
#elif COPY_DATA_SZ == 4
ldmia r2, {r6-r9} // load additional data
#elif COPY_DATA_SZ == 5
ldmia r2, {r6-r10} // load additional data
#endif
FMACS4 (8,9,10,11, 24,25,26,27, 2,2,2,2) // pos.z
FMACS4 (12,13,14,15, 20,21,22,23, 4,4,4,4) // normal.y
vstmia.32 r3!, {s8-s10} // store pos
FMACS4 (12,13,14,15, 24,25,26,27, 5,5,5,5) // normal.z
add r0, r0, r4 // inc srcData
vstmia.32 r3!, {s12-s14} // store normal
add r2, r2, r4 // inc srcAddData
cmp r0, r1 // check cycle
#if COPY_DATA_SZ == 1
stmia r3!, {r6} // save additional data
#elif COPY_DATA_SZ == 2
stmia r3!, {r6-r7} // save additional data
#elif COPY_DATA_SZ == 3
stmia r3!, {r6-r8} // save additional data
#elif COPY_DATA_SZ == 4
stmia r3!, {r6-r9} // save additional data
#elif COPY_DATA_SZ == 5
stmia r3!, {r6-r10} // save additional data
#endif
bcc LOOP_NAME
#elif LOOP_XYZNT
.align 4
LOOP_NAME:
mov r5, r0
pld [r0, #512] // prefetch
vldmia.32 r5!, {s0-s2} // load pos
FCPYS4 (8,9,10,11, 28,29,30,31) // pos.w
vldmia.32 r5!, {s3-s5} // load normal
FMACS4 (8,9,10,11, 16,17,18,19, 0,0,0,0) // pos.x
FMULS4 (12,13,14,15, 16,17,18,19, 3,3,3,3) // normal.x
FMACS4 (8,9,10,11, 20,21,22,23, 1,1,1,1) // pos.y
#if COPY_DATA_SZ == 1
ldmia r2, {r6} // load additional data
#elif COPY_DATA_SZ == 2
ldmia r2, {r6-r7} // load additional data
#elif COPY_DATA_SZ == 3
ldmia r2, {r6-r8} // load additional data
#elif COPY_DATA_SZ == 4
ldmia r2, {r6-r9} // load additional data
#elif COPY_DATA_SZ == 5
ldmia r2, {r6-r10} // load additional data
#endif
FMACS4 (8,9,10,11, 24,25,26,27, 2,2,2,2) // pos.z
FMACS4 (12,13,14,15, 20,21,22,23, 4,4,4,4) // normal.y
vstmia.32 r3!, {s8-s10} // store pos
FMACS4 (12,13,14,15, 24,25,26,27, 5,5,5,5) // normal.z
vldmia.32 r11, {s0-s3} // load tangent
add r0, r0, r4 // inc srcData
FMULS4 (8,9,10,11, 16,17,18,19, 0,0,0,0) // tangent.x
vstmia.32 r3!, {s12-s14} // store normal
FMACS4 (8,9,10,11, 20,21,22,23, 1,1,1,1) // tangent.y
cmp r0, r1 // check cycle
FMACS4 (8,9,10,11, 24,25,26,27, 2,2,2,2) // tangent.z
#if COPY_DATA_SZ == 1
stmia r3!, {r6} // save additional data
#elif COPY_DATA_SZ == 2
stmia r3!, {r6-r7} // save additional data
#elif COPY_DATA_SZ == 3
stmia r3!, {r6-r8} // save additional data
#elif COPY_DATA_SZ == 4
stmia r3!, {r6-r9} // save additional data
#elif COPY_DATA_SZ == 5
stmia r3!, {r6-r10} // save additional data
#endif
fcpys s11, s3 // copy tangent.w
vstmia.32 r3!, {s8-s11} // store tangent
add r2, r2, r4 // inc srcAddData
add r11, r11, r4 // inc srcTangent
bcc LOOP_NAME
#elif LOOP_SPRITE
.align 4
LOOP_NAME:
mov r5, r0
pld [r0, #512] // prefetch
vldmia.32 r5!, {s0-s2} // load pos
FCPYS4 (8,9,10,11, 28,29,30,31) // pos.w
FMACS4 (8,9,10,11, 16,17,18,19, 0,0,0,0) // pos.x
ldmia r2, {r7-r8} // load uv
FMACS4 (8,9,10,11, 20,21,22,23, 1,1,1,1) // pos.y
add r0, r0, r4 // inc srcData
FMACS4 (8,9,10,11, 24,25,26,27, 2,2,2,2) // pos.z
add r2, r2, r4 // inc srcAddData
vstmia.32 r3!, {s8-s10} // store pos
cmp r0, r1 // check cycle
stmia r3!, {r6-r8} // save color and uv
bcc LOOP_NAME
#endif
// VFP_VECTOR_LENGTH_ZERO
ldmfd sp!, {r4-r11}
vpop {d0-d15}
bx lr
#endif // STRIDED_INPUT
|
